1. 白马号首页
  2. 投稿

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

白马号 • • 投稿

自己编写的一个DOS批处理，用于批量修改文件名或扩展名。

实现逻辑：

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

操作：批处理运行后会在当前文件夹下生成一个错误信息文件batResult.txt

字符替换：

示例一：将文件名中的“5”替换成“99”

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

原文件

运行批处理文件batRename2.bat:

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

结果：

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

示例二：将“废柴兄弟”改成“上海滩”，并将扩展名改为“bat”

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

操作：

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

结果：

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

改成新文件名：将所有扩展名为bat文件改成新文件名newBAT，后缀改为ttt

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

操作：

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

结果：

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

程序实现方法一：

@echo off

rem 切换为utf-8编码
::Chcp 65001
::切换中文
Chcp 936 > nul

rem 启用延缓环境变量扩展
setlocal EnableDelayedExpansion

echo **可修改当前文件夹下所有的文件名或字符及扩展名**
echo *****将此批处理文件拷入需要修改的文件夹中******
set option=9
set cnt=0
set skipChar=/*?:"<>|^!

echo **   请选择操作...        **
echo ** 1 替换部分字符或扩展名 **
echo ** 0 换成全新文件名       **

:selectOption
set /p option= 》》请选择操作选项:
if %option%==1 ( goto endSelectOption
) else if %option%==0 (goto endSelectOption) 
set /a cnt+=1
if %cnt% GTR 2 (goto end) else (goto selectOption)
:endSelectOption

echo ------要修改的原文件信息，回车结束输入-------
set retVal=0

:inputOfi
set oldFile=
set retVal=0
if %option%==1 (  set /p oldFile="》》请输入要替换的文件名/文字(必输入)："
) else (set /p oldFile="》》请输入要修改的文件名/文字(不输入则包括当前文件夹下所有文件): ")

if %option%==1 (if "%oldFile%"=="" echo 被替换字符不能为空！& goto inputOfi 
) else (if "%oldFile%"=="*"  goto inputOfe
	if "%oldFile%"=="" ( set oldFile=*
			     goto inputOfe))

@echo !oldFile! | findstr "[!skipChar!]" > nul
if "!errorlevel!"=="0" (echo ！！输入的文件名/字符"!oldFile!"错误！！
		rem 如果用%skipChar%则出现“此时不应有 >”的错误提示。
		echo ！！字符中不能包含"!skipChar!"中的字符 ！！
		goto inputOfi)

:inputOfe
set oldFExt=
set retVal=0
set /p oldFExt= 》》请输入原文件扩展名（不输入则包括所有扩展名):

if "%oldFExt%"=="*" goto endInputOfe
if "%oldFExt%"=="" (set oldFExt=*
) else (@echo !oldFExt!| findstr "[^0-9A-Za-z]" > nul
	if "!errorlevel!"=="0" (
			echo ！！扩展名"%oldFExt%"错误！！
			echo ！！请输入0-9,A-Z,a-z之间的字符！！
			goto inputOfe))
:endInputOfe
echo === 查找范围："*!oldFile!*.!oldFExt!" ===

echo -----新的文件信息，回车结束输入------
:inputNfi
set newFile=
set retVal=0
set /p newFile="》》请输入新的文件名/字符(必输入)："

if not "%newFile%"=="" (
	@echo !newFile! | findstr "[!skipChar!]" > nul
	if "!errorlevel!"=="0" (
		echo ！！输入的文件名/字符"%newFile%"错误！！
		echo ！！字符中不能包含"!skipChar!"中的字符 ！！
		goto inputNfi)
) else (echo 新的文件名/字符不能为空！& goto inputNfi)

:inputNfe
set newFExt=
set retVal=0
if %option%==1 (if "!oldFExt!"=="*" (goto endInputNfe ))
set /p newFExt="》》输入新的文件扩展名(不输入则保留原扩展名)：")

if "!newFExt!" neq "" (
	@echo !newFExt!| findstr "[^0-9A-Za-z]" > nul
	if "!errorlevel!"=="0" (
		echo ！！   扩展名"%newFExt%"错误   ！！
		echo ！！请输入0-9,A-Z,a-z之间的字符！！
		goto inputNfe)
)
:endInputNfe

echo === 查找范围： "*!oldFile!*.!oldFExt!" ===
if %option%==1 (if "%newFExt%" neq "" (echo === 替换为：   "*!newFile!*.!newFExt!" === 
		) else (echo === 替换为：   "*!newFile!*.原扩展名" === )
) else (if "%newFExt%"=="" (echo === 新的内容为："!newFile!000N.原扩展名" ===
	) else (echo === 新的内容为："!newFile!000N.!newFExt!" ===))

rem --------------------处--理-------------------------
set ttl=0
set a=1
set aStr=0001

set /p confirm=请确认是否修改？(输入：Y-是，N-否)
if "%confirm%" neq "Y" (if "%confirm%" neq "y" goto end)

rem set oft="%oft%.%oldFExt%"
for /f "delims="  %%i in ( 'dir /b /a-d "*%oldFile%*.%oldFExt%" ' ) do (
    if "%oldFile%"=="*" (@echo %%~ni | findstr /i ".%oldFile%" > nul
    ) else (@echo %%~ni | findstr /iL /c:"%oldFile%" > nul)
    if "!errorlevel!"=="0" (
    rem 不需修改当前批处理文件名（本身）
    if not "%%~ni"=="%~n0" (
	set /a ttl+=1
	::只有文件名，如test.txt时，只有test
       	set file=%%~ni
	::只有扩展名，如test.txt时，只有.txt
	set ext=%%~xi
	
	if !option!==1 (set file=!file:%oldFile%=%newFile%!
		if "%newFExt%"=="" (
			ren "%%i" "!file!!ext!" 1>> batResult.txt 2<&1
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!!ext!"-- >>batResult.txt
			) else (set /a a+=1)
		) else (ren "%%i" "!file!.%newFExt%" 2>> batResult.txt
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!.%newFExt%"-- >>batResult.txt
			) else (set /a a+=1))
	) else (set file=%newFile%!aStr!
		if "%newFExt%"=="" (
			ren "%%i" "!file!!ext!" 1>> batResult.txt 2<&1
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!!ext!"-- >>batResult.txt
			) else (set /a a+=1
				if !a!  LSS 10 (set aStr=000!a!
				) else if !a! LSS 100  (set aStr=00!a!
				) else if !a! LSS 1000 (set aStr=0!a!))
		) else (ren "%%i" "!file!.%newFExt%" 2>> batResult.txt
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!.%newFExt%"-- >>batResult.txt
			) else (set /a a+=1
				if !a!  LSS 10 (set aStr=000!a!
				) else if !a! LSS 100  (set aStr=00!a!
				) else if !a! LSS 1000 (set aStr=0!a!))
		)
	)
rem	echo a=!a!,oldFile-^> newFile:"%%i" -^> "!file!.%newFExt%"
    )
    )
)
:end
set /a a-=1
echo 总处理文件数：!ttl! ,处理成功数：!a!
endlocal
pause
goto :eof

程序实现方法二：与方法一区别在于判断字符的合法性方面

@echo off
rem 切换为utf-8编码
::Chcp 65001
::切换中文
Chcp 936 > nul

rem 启用延缓环境变量扩展
setlocal EnableDelayedExpansion

echo **可修改当前文件夹下所有的文件名或字符及扩展名**
echo *****将此批处理文件拷入需要修改的文件夹中******
set option=9
set cnt=0
set skipChar=/*?:"<>|^!

echo **   请选择操作...        **
echo ** 1 替换部分字符或扩展名 **
echo ** 0 换成全新文件名       **

:selectOption
set /p option= 》》请选择操作选项:
if %option%==1 ( goto endSelectOption
) else if %option%==0 (goto endSelectOption) 
set /a cnt+=1
if %cnt% GTR 2 (goto end) else (goto selectOption)
:endSelectOption

echo ------要修改的原文件信息，回车结束输入-------
set retVal=0

:inputOfi
set oldFile=
set retVal=0
if %option%==1 (  set /p oldFile="》》请输入要替换的文件名/文字(必输入)："
) else (set /p oldFile="》》请输入要修改的文件名/文字(不输入则包括当前文件夹下所有文件): ")

if %option%==1 (if "%oldFile%"=="" echo 被替换字符不能为空！& goto inputOfi 
) else (if "%oldFile%"=="*"  goto inputOfe
	if "%oldFile%"=="" ( set oldFile=*
			     goto inputOfe))
rem echo oldFile="!oldFile!",!oldFile!,"%oldFile%",%oldFile%
rem call :checkFileChar "%oldFile%"  %skipChar%  oldFile中如有！用%会出错.
call :checkFileChar "!oldFile!" %skipChar%
if !retVal!==1 (echo ！！输入的文件名/字符"%oldFile%"错误！！
		rem 如果用%skipChar%则出现“此时不应有 >”的错误提示。
		echo ！！字符中不能包含"!skipChar!"中的字符 ！！
		goto inputOfi)

:inputOfe
set oldFExt=
set retVal=0
set /p oldFExt= 》》请输入原文件扩展名（不输入则包括所有扩展名):

if "%oldFExt%"=="*" goto endInputOfe
if "%oldFExt%"=="" (set oldFExt=*
) else (call :checkExtChar "!oldFExt!" "O"
	if !retVal!==1 (echo ！！扩展名"%oldFExt%"错误！！
			echo ！！请输入0-9,A-Z,a-z之间的字符！！
			goto inputOfe))
:endInputOfe
echo === 查找范围："*!oldFile!*.!oldFExt!" ===

echo -----新的文件信息，回车结束输入------
:inputNfi
set newFile=
set retVal=0
set /p newFile="》》请输入新的文件名/字符(必输入)："

if not "%newFile%"=="" (call:checkFileChar "!newFile!" %skipChar%
	if !retVal!==1 (echo ！！输入的文件名/字符"%newFile%"错误！！
			echo ！！字符中不能包含"!skipChar!"中的字符 ！！
			goto inputNfi) 
) else (echo 新的文件名/字符不能为空！& goto inputNfi)

:inputNfe
set newFExt=
set retVal=0
if %option%==1 (if "!oldFExt!"=="*" (goto endInputNfe ))
set /p newFExt="》》输入新的文件扩展名(不输入则保留原扩展名)：")

if "!newFExt!" neq "" (call:checkExtChar "!newFExt!" "N"
	if !retVal!==1 (echo ！！   扩展名"%newFExt%"错误   ！！
			echo ！！请输入0-9,A-Z,a-z之间的字符！！
			goto inputNfe)
)
:endInputNfe

echo === 查找范围： "*!oldFile!*.!oldFExt!" ===
if %option%==1 (if "%newFExt%" neq "" (echo === 替换为：   "*!newFile!*.!newFExt!" === 
		) else (echo === 替换为：   "*!newFile!*.原扩展名" === )
) else (if "%newFExt%"=="" (echo === 新的内容为："!newFile!000N.原扩展名" ===
	) else (echo === 新的内容为："!newFile!000N.!newFExt!" ===))

rem --------------------处--理-------------------------
set ttl=0
set a=1
set aStr=0001

set /p confirm=请确认是否修改？(输入：Y-是，N-否)
if "%confirm%" neq "Y" (if "%confirm%" neq "y" goto end)

rem set oft="%oft%.%oldFExt%"
for /f "delims="  %%i in ( 'dir /b /a-d "*%oldFile%*.%oldFExt%" ' ) do (
    if "%oldFile%"=="*" (@echo %%~ni | findstr /i ".%oldFile%" > nul
    ) else (@echo %%~ni | findstr /iL /c:"%oldFile%" > nul)
    if "!errorlevel!"=="0" (
    rem 不需修改当前批处理文件名（本身）
    if not "%%~ni"=="%~n0" (
	set /a ttl+=1
	::只有文件名，如test.txt时，只有test
       	set file=%%~ni
	::只有扩展名，如test.txt时，只有.txt
	set ext=%%~xi
	
	if !option!==1 (set file=!file:%oldFile%=%newFile%!
		if "%newFExt%"=="" (
			ren "%%i" "!file!!ext!" 1>> batResult.txt 2<&1
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!!ext!"-- >>batResult.txt
			) else (set /a a+=1)
		) else (ren "%%i" "!file!.%newFExt%" 2>> batResult.txt
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!.%newFExt%"-- >>batResult.txt
			) else (set /a a+=1))
	) else (set file=%newFile%!aStr!
		if "%newFExt%"=="" (
			ren "%%i" "!file!!ext!" 1>> batResult.txt 2<&1
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!!ext!"-- >>batResult.txt
			) else (set /a a+=1
				if !a!  LSS 10 (set aStr=000!a!
				) else if !a! LSS 100  (set aStr=00!a!
				) else if !a! LSS 1000 (set aStr=0!a!))
		) else (ren "%%i" "!file!.%newFExt%" 2>> batResult.txt
			if "!errorlevel!" neq "0" ( echo --原文件"%%i",新文件名"!file!.%newFExt%"-- >>batResult.txt
			) else (set /a a+=1
				if !a!  LSS 10 (set aStr=000!a!
				) else if !a! LSS 100  (set aStr=00!a!
				) else if !a! LSS 1000 (set aStr=0!a!))
		)
	)
rem	echo a=!a!,oldFile-^> newFile:"%%i" -^> "!file!.%newFExt%"
    )
    )
)
:end
set /a a-=1
echo 总处理文件数：!ttl! ,处理成功数：!a!
endlocal
pause
goto :eof

rem ---------检查文件名-------参数带双引号---------------
:checkFileChar
rem set proVar=%1& set proVar=!proVar:~1,-1!	也可写成这样
set proVar=%~1
rem set proVar=!proVar:~1,-1! 去掉双引号，效果同%~1
set noCharTmp=%2
set cnt2=0
set retVal=0

:cyc2
if "!proVar:~%cnt2%,1!"==""  (set retVal=0&goto :eof)
rem echo 第%cnt2%个字符:"!proVar:~%cnt2%,1!","!proVar!",%proVar%,传入参数:%1,最后一个字符：'%proVar:~-1%'

set cnt3=0
:cyc3
rem echo 第%cnt3%个排除字符："!noCharTmp:~%cnt3%,1!"+
if "!noCharTmp:~%cnt3%,1!"=="" (set retVal=0&set /a cnt2+=1 &goto cyc2)
if "!noCharTmp:~%cnt3%,1!"=="!proVar:~%cnt2%,1!"  (
			set retVal=1
			goto :eof
) else (set /a cnt3+=1
	goto cyc3 )
rem ---------检查扩展名-------参数带双引号--------------
rem ----- 只能输入0-9，A-Z,a-z,(原文件加:*、?) -----------
:checkExtChar
rem set proVar2=%1 & set proVar2=!proVar2:~1,-2! 此行问题：在%1 &间有一个空格
set proVar2=%~1
rem set proVar2=%proVar2:~1,-1%
set flag=%2
set cnt4=0
set retVal=0
:cyc4
rem echo %cnt4% + "!proVar2:~%cnt4%,1!"
if "!proVar2:~%cnt4%,1!"==""     (set retVal=0&goto :eof)
rem if %flag%=="O" (
rem	if "!proVar2:~%cnt4%,1!"=="*" (set /a cnt4+=1&goto cyc4
rem	) else if "!proVar2:~%cnt4%,1!"=="?" (set /a cnt4+=1&goto cyc4) )

if "!proVar2:~%cnt4%,1!" LSS "0" (set retVal=1&goto :eof)
if /i "!proVar2:~%cnt4%,1!" GTR "z" (set retVal=1&goto :eof)
if "!proVar2:~%cnt4%,1!" GTR "9" (
	if /i "!proVar2:~%cnt4%,1!" LSS "a" (set retVal=1&goto :eof))

rem if "!proVar2:~%cnt4%,1!" GTR "Z" (
rem 	if "!proVar2:~%cnt4%,1!" LSS "a" (set retVal=1&goto :eof))
rem echo %cnt4% + "!proVar2:~%cnt4%,1!" + 4
set /a cnt4+=1
goto cyc4

注意：要确保将此批处理文件放在需要改名的文件夹下，尽量不要输入DOS命令中的特殊字符，如 *./^ | 等。

findstr相关补充说明：默认启用正则表达式

“/L” ：如果要关闭正则表达式，即把^$<.*等当成普通的字符，则用/L开关

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

此处的$不在用于判断“ese”是最后字符了

“.*” : 代表所有

“/c:” : 使用指定字符串作为文字搜索字符串,搜索字符串中的”.”或”*”等符号不再是通配符,只是普通的句号、星号字符

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

“/d” : 从用分号分隔的指定目录里查找所有txt文件里的“hello”字符串

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

“/a:attr” : 指定目录和文件名的颜色，有两个字符时，第一个表示底色，第二个表示字体颜色，查color /?可知颜色代码如下：

  • 0 = 黑色 8 = 灰色
  • 1 = 蓝色 9 = 淡蓝色
  • 2 = 绿色 A = 淡绿色
  • 3 = 浅绿色 B = 淡浅绿色
  • 4 = 红色 C = 淡红色
  • 5 = 紫色 D = 淡紫色
  • 6 = 黄色 E = 淡黄色
  • 7 = 白色 F = 亮白色

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

另外，下一目录为什么接在上一行的后面？是因为上一行最后没有回车引起的

“/f:file” : 将要查找范围内的文件名存放在一个文件中“file”中，从这些文件中搜索“hello”

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

电脑文件名批量修改怎么操作（批量修改文件名或扩展名方法）

声明：所有白马号原创内容，未经允许禁止任何网站及个人转载、采集等一切非法引用。本站已启用原创保护，有法律保护作用，否则白马号保留一切追究的权利。发布者：白马号，转转请注明出处：https://www.bmhysw.com/article/38062.html

赞 (0)
打赏 微信扫一扫 微信扫一扫 支付宝扫一扫 支付宝扫一扫
白马号白马号
0

相关推荐

  • Win10如何合并小图标？Win10合并小图标步骤 投稿

    Win10如何合并小图标？Win10合并小图标步骤

    Win10如何合并小图标？Win10合并小图标步骤 Step1：点击任务栏 Step2：选择“任务栏设置” Step3：开启“合并任务栏按钮” Step4：选择“一直合并” Step1：点击任务栏 首先，我们需要点击任务栏，这样才能进行任务栏设置。任务栏通常位于屏幕底部，如果您的任务栏已经被隐藏，可以将鼠标指针移动到屏幕底部，任务栏就会自动弹出。 Step2…

    2023-07-29
    00
  • Win10卸载更新右键没反应怎么办？ 投稿

    Win10卸载更新右键没反应怎么办？

    Win10卸载更新右键没反应怎么办？ 问题原因 解决方法 总结 问题原因 在Windows 10系统中，更新是非常重要的，因为它可以解决一些安全漏洞和性能问题。但是，有时候在卸载更新时可能会出现右键没有反应的情况，这是什么原因呢？ 这种情况通常是由于系统文件损坏或者更新文件本身出现问题所导致的。此外，也有可能是由于安装的杀毒软件或其他第三方软件干扰了系统更新…

    2023-07-26
    00
  • Linux提示Unable to locate package该如何处理？ 投稿

    Linux提示Unable to locate package该如何处理？

    Linux提示Unable to locate package该如何处理？ 出现该提示的原因 解决该问题的方法 总结 出现该提示的原因 在使用Linux系统时，有时候会出现“Unable to locate package”的提示，这是因为apt-get无法找到对应的软件包。这可能是由于以下几个原因导致的： 软件包名称拼写错误 软件包源列表中没有该软件包 软…

    2023-06-28
    00

  • eplan p8 2.7安装教程win7（eplan安装图解详情）

    EPLAN作为电气计算机辅助设计时代的先锋，是一款电气设计领域的知名软件。并以电气设计为基础的跨专业的设计平台，包括电气设计、流体设计、仪表设计、机械设计（如机柜设计）等。 eplan2.7（32位、64位）下载地址： 安装步骤： 1、解压上面下载的软件。 2、双击打开解压文件夹中setup程序。 3、点击继续。 4、勾选我接受该许可协议，然后点击继续。 5…

    2022-08-29 • 投稿
    00
  • 真正纯净的Win7系统介绍（纯净版系统特点和推荐） 投稿

    真正纯净的Win7系统介绍（纯净版系统特点和推荐）

    真正纯净的Win7系统介绍 纯净版系统特点 纯净版系统推荐 纯净版系统特点 纯净版Win7系统是指在原版系统的基础上去除了一些不必要的软件和功能，使系统更加简洁、稳定、流畅，适合对系统性能要求较高的用户。以下是纯净版系统的特点： 去除了系统自带的一些软件和功能，减少系统负担，提高运行速度 系统更加稳定，不会出现一些不必要的错误和故障 系统更加安全，减少了一些…

    2023-05-28
    00

联系我们

QQ:183718318

在线咨询： QQ交谈

邮件：183718318@qq.com

工作时间：周一至周五，9:30-18:30，节假日休息

关注微信